\Extinction and spontaneous recovery

\This program has two phases

\Initially the program reinforces the rat

\90 in a CRF schedule

\NOTE TO STUDENT: Run equipment test before beginning experiment.

\Ask TF for details, if necessary.

\Define constants for stimuli and responses

^RightLever=1

^LeftLever=2

^OmniLever=3

^Handswitch=4

^Houselight=1

^RightLight=2

^Feeder=3

^LeftLight=4

^RightNoise=5

^LeftNoise=6

^ExternalLight=7

\Array A is used to record the number of responses in each of the

\ three extinction trials

\Array B is used to record the amount of time to meet the

\ extinction criteria.

\Array C is used to record time elapsed between responses to

\ generate a cumulative record for the entire experiment

\ARRAY D is used to keep the number of responses

\ minute by minute throughout the experiment.

\#Z1 Starts and stops timer during extinction and makes a pip in event

\ line 0 to indicate extinction periods.

\#Z2 is used to reset the timer used in the cumulative record

\#Z3 is used to make reinforcement pips

DIM A=3

DIM B=3

DIM C=2000

DIM D=120

\*******************************************************************

\Initially 90 bar presses will be reinforced

s.s.1,

s1,

#Start:--->s2 \Start command will be issued from the keyboard

\Ask your TF to do this when you are ready

s2,

#R^Handswitch:On^Houselight--->s3 \First turn the house light on with

\your Handswitch.

s3,

#R^Leftlever ! #R^RightLever:On^Feeder;Z3;Add R--->s4

\Lever presses deliver a pellet.

\Variable R keeps track the No.

\of pellets.

s4,

.05":Off^Feeder;IF R>=90[@true,@false] \After 90 reinforced bar-presses

\go to extinction in S5.

@true:Z1 --->s5 \Z1 Starts clock in the first

@false:show 1,Bar,R--->s3 \extinction trial.

\This part of the program is for the 3 extinction phases

\Variable E keeps track of the extinction trial No.

s5,

#R^RightLever ! #R^Leftlever: ADD A(E)--->s5

\IN S5 the lever presses are recorded

\recorded in the 3 extinction trials.

\If the subject presses a lever this

\state will start again and will

\only go to the next if two minutes

\go by without a lever press.

2':Off^Houselight;Set B(E)=T;ADD E;If E>=3[@true,@false]

@true:--->STOPABORTFLUSH

@false: Show 1, EXTNO=, E,2,EXTRS= ,A(E-1), 3, EXTSEC= , B(E-1);

Z1;SET B(E)=-987.987,A(E)=-987.987--->S6

\If two minutes without responding go by the house light goes off.

\Take you subject of the operant chamber and wait 10 min before

\the next trial. Start by pressing you Handswitch.

s6,

#R^Handswitch:Z1;Set B(E)=0,A(E)=0;On^HouseLight--->s5

\************************************************************************

\The following stateset is used

\as a timer for the 3 Extinction trials.

S.S.2,

s1,

#Start:--->s2

s2,

#Z1:Set T=0--->s3

s3,

1":ADD T--->SX

#Z1:--->s2

\**********************************************************************

\Statements for the Cumulative record to follow

\S.S.3, Increments time

S.S.3,

s1,

#start--->s2

s2,

#z2--->s2

0.1": ADD U--->SX

\**********************************************************************

S.S.4,

s1,

#Start:--->S2

s2,

#R^RightLever ! #R^LeftLever: Set C(I)= U+0.1,U=0;Z2;ADD I;

IF I= 2000 [@T,@F]

@T:--->STOPABORTFLUSH

@F:SET C(I)= -987.987--->SX

#Z1:Set C(I)= U+.60,U=0;Z2;ADD I; \Generates a pip in event record 0

Set C(I)= 0.50;ADD I;IF I=2000 [@T,@F]

@T:--->STOPABORTFLUSH

@F:SET C(I)= -987.987 --->sx

\***************************************************************************

S.S.5, \Makes a pip reinforcement pip.

s1,

#Start:--->s2

s2,

#z3: Set C(I)=0.2;ADD I; IF I=2000 [@T,@F]

@T:--->STOPABORTFLUSH

@F:SET C(I)= -987.987--->SX

\**************************************************************************

\S.S.6 Keeps a record of the number of responses

\each minute of the experiment

\Session will end automatically after 120'.

S.S.6,

s1,

#start:--->s2

s2,

#R^Handswitch:On^Houselight--->s3

s3,

#R^Leftlever ! #R^RightLever:ADD D(F)--->SX

#z1: ADD F;Set D(F)=0,D(F+1)=-987.987;z7--->s3 \jumps to end of minute

\and flashes lights

1':ADD F;Set D(F)=0,D(F+1)=-987.987;z6;IF F>=120 [@true,@false]

@true:--->STOPABORTFLUSH

@false:--->sx

#k99:--->STOPABORTFLUSH \IF CASE YOU NEED TO LEAVE EARLY

\**********************************************************************

s.s.7, \flashes light when receives z6 every minute

\ double flashes for z7 when extinction begins and stops

s1,

#z6:on ^ExternalLight--->s4

#z7:on ^ExternalLight--->s2

s2,

.1":off ^ExternalLight--->s3

s3,

.1":on ^ExternalLight--->s4

s4,