;mlevprtpxcpd.mck;
;avance-version
;homonuclear Hartman-Hahn transfer using MLEV17 sequence
;   for mixing
;using two power levels for excitation and spinlock
;phase sensitive using TPPI
;A. Bax & D.G. Davis, J. Magn. Reson. 65, 355-360 (1985)
;modified to include x-decoupling 02/24/98
;modified from mlevprtpxcdp.dv 5/18/99 to include documentation and definitions

#include <Avance.incl>


"p5=p6*.667"
"p7=p6*2"
;;"d0=3u"
"d11=30m"
"d12=20u"
"d13=3u"


1 ze 
2 d11 
3 d12 pl9:f1
  d1 cw:f1
  d13 do:f1
  d12 pl1:f1
  d12 pl2:f2
  p1 ph1
  d0
  (p4 ph8):f2
  d0
  d12 pl10:f1
  d12 pl12:f2
  (p17 ph26)
4 (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph22 p7 ph23 p6 ph22)
  (p6 ph24 p7 ph25 p6 ph24)
  (p6 ph24 p7 ph25 p6 ph24)
  (p5 ph23)
  lo to 4 times l1 
  (p17 ph26) 
  go=2 ph31 cpd2:f2
  d11 wr #0 if #0 id0 ip1 zd
  lo to 3 times td1
exit 
  

ph1=0 2 2 0 1 3 3 1
ph22=3 1 3 1 0 2 0 2
ph23=0 2 0 2 1 3 1 3
ph24=1 3 1 3 2 0 2 0
ph25=2 0 2 0 3 1 3 1
ph26=0 2 0 2 1 3 1 3
ph31=0 2 2 0 1 3 3 1
ph8=0


;pl1 : f1 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;pl10: f1 channel - power level for TOCSY-spinlock
;pl2 : f2 channel - power level for hard X 180 pulse
;pl12: f2 channel - power level for X nucleus decoupling (pcpd)
;p1 : f1 channel -  90 degree high power pulse
;p5 : f1 channel -  60 degree low power pulse
;p6 : f1 channel -  90 degree low power pulse
;p7 : f1 channel - 180 degree low power pulse
;p17: f1 channel - trim pulse                             [2.5 msec]
;p4 : f2 channel - hard 180 pulse
;pcpd2: f2 channel - X nucleus decoupling 90 pulse    [200 usec]
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [3 usec]
;L1: loop for MLEV cycle: (((p6*64) + p5) * l1) + (p17*2) = mixing time
;in0: 1/(4 * SW) = DW/2
;nd0: 4
;NS: 8 * n
;DS: 16
;td1: number of experiments
;MC2: TPPI